[Win8制作] WIN8映像合并一键批处理(注释)

WIN8映像合并一键批处理下载：

http://pan.baidu.com/share/link?shareid=181125&uk=3944978029

WIN8映像合并一键批处理(注释)－－－WORD版本

http://pan.baidu.com/share/link?shareid=181126&uk=3944978029

::---------------------------------------------以下是批处理内容与注释---------------------------------------------::

@echo off

color 2f

ECHO 文中注释用REM开头表示，蓝色字。

ECHO.

ECHO ##------------------------------------------------##

ECHO ## 本批处理用于WIN8 简体中文 64位合集制作 ##

ECHO ##------------------------------------------------##

ECHO.

ECHO **本批处理应使用管理员身份运行**

ECHO.

ECHO 所选分区根目录下应有以下特定文件夹和文件：

ECHO 1、$OEM$文件夹、X64WIN8ISO文件夹

ECHO 2、$OEM$里包含：$$文件夹、imagex.exe、oscdimg.exe、ei.cfg、product.ini。

ECHO 3、应事先WIN8 PRO[非VL]原版ISO中内容全部提取到X64WIN8ISO文件夹中

ECHO.

ECHO 说明

ECHO a、若要整合企业版，需事先复制其instll.wim到分区根目录，并改名为x64ent.wim

ECHO b、若要整合Server2012数据中心版、标准版的GUI版，需事先复制其原版instll.wim到分区根目录，并改名为x64Ser.wim

ECHO c、若未检索到x64ent.wim批处理将自动略过。

ECHO d、整合越多版本，所需的用于操作的临时空闲空间越大。

ECHO.

ECHO 应保证有足够的空闲空间 25G以上 做为操作分区。上述文件夹应置放在此分区。

SET /P PART=. (C、D、E、F、G、H、I...)请选择：

ECHO.

ECHO 按“任意键”开始自动处理，现在开始吗？

pause >nul

IF NOT EXIST %PART%:\X64WIN8ISO goto end

IF NOT EXIST %PART%:\X64WIN8ISO\sources\install.wim goto end

IF NOT EXIST %PART%:$OEM$ goto end

IF NOT EXIST %PART%:$OEM$\imagex.exe goto end

IF NOT EXIST %PART%:$OEM$\oscdimg.exe goto end

IF NOT EXIST %PART%:$OEM$\product.ini goto end

IF NOT EXIST %PART%:$OEM$\ei.cfg goto end

IF NOT EXIST %PART%:$OEM$$$ goto end

REM 上段几行检测所需的材料与工具是否在批处理所要求的路径上。

IF EXIST %PART%:\install.wim (

rename %PART%:\install.wim old_install.wim

)

IF EXIST %PART%:\tempwim (

rename %PART%:\tempwim old_temp

)

REM 上段几行检测是否有以前的install.wim在分区根目录上，如果有，将被重命名，因为我们有新的install.wim要移到根目录。

cls

ECHO.

ECHO ##------------------------------------------------##

ECHO ## 本批处理用于WIN8 简体中文 64位合集制作 ##

ECHO ##------------------------------------------------##

ECHO.

ECHO.

ECHO -------------------准备工作与映像重命名------------------------

ECHO.

md %PART%:\tempwim

REM 上一行是创建一个用于挂载WIM中的卷映像的临时目录。%PART%:\表示你在前面选定的工作分区。

move %PART%:\X64WIN8ISO\sources\install.wim %PART%:\

REM 上一行是移动X64WIN8ISO\sources中的install.wim到分区根目录。

%PART%:$OEM$\imagex.exe /info %PART%:\install.wim 1 "Windows 8 专业版 64位" "Windows 8 专业版 64位"

%PART%:$OEM$\imagex.exe /info %PART%:\install.wim 2 "Windows 8 标准版 64位" "Windows 8 标准版 64位"

REM 上二行是使用IMAGEX.EXE来重命名install.wim的两个卷映像名称，并加上了“64位”字样，将来如果要与32位的合并，这个重命名就派上用场了。 /info是IMAGEX的重命名命令，第一个双引号中的内容是卷映像名称，安装时会出现在版本选择框内，第二个双引号是卷映像的描述，出现在版本选择框下方。

REM 关于WIM与卷映像，卷映像在WIM文件中。一个WIM文件中可以有1个或多个卷映像。从一个WIM文件中导出一个卷映像，可以独立成为一个新的WIM文件，也可以加入一个已有卷映像的WIM中，卷映像的编号是最后一个。

REM 了解一下install.wim中卷映像信息，在WIN8中管理员身份运行：DISM /Get-WimInfo /WimFile:F:\install.wim >F:\install.txt

REM 这样F:\install.txt就保存有install.wim的卷映像信息，可供查看。 F:\是假设路径

ECHO.

ECHO -------------------以下是 Win8 Core 映像处理------------------------

ECHO.

DISM /Mount-Wim /wimfile:%PART%:\install.wim /index:2 /MountDir:%PART%:\tempwim

REM 上一行指使用DISM WIN8版 挂载install.wim中的2号映像。/Mount-Wim是整行命令的行动信号 挂载 ，/wimfile表示要挂载哪个WIM文件，/index表示WIM文件中的哪个编号的卷映像，/MountDir表示挂载到哪个临时目录。

Dism /Image:%PART%:\tempwim /Set-ProductKey:FB4WR-32NVD-4RW79-XQFWH-CYQG3

REM 上一行对临时挂载目录中的2号卷映像添加安装KEY。/Set-ProductKey是添加安装KEY的命令。

DISM /commit-image /MountDir:%PART%:\tempwim

REM 上一行临时挂载目录中的2号卷映像发生了变化，使用 /commit-image 将这此变化保存进WIM文件，但仍处于挂载状态，类似一个ISO被加到虚拟光驱一样。此时WIM中的2号卷映像整合了安装KEY。

ECHO －－－CORE加入ADMIN映像

xcopy %PART%:$OEM$$$ %PART%:\tempwim\windows /e /y

REM 上行使用拷贝命令，将用于制作能自动启用内置管理 简称Admin 所需文件资料复制到临时挂载目录，这样临时挂载目录增加了一些内容。/e与/y是拷贝命令参数。

DISM /commit-image /MountDir:%PART%:\tempwim /append

REM 上行命令是向WIM文件添加一个卷映像，名称与之前2号映像相同。WIM中原有2个卷映像，此时增加了一个卷映像 第3号卷映像 ，这个卷映像与2号卷映像不同的在于增加了能自动启用内置管理员的功能。/commit-image表示保存映像，/append表示添加，合起说就是以增加的方式保存卷映像。

DISM /unmount-Wim /MountDir:%PART%:\tempwim /discard

REM 撤消挂载。这之前挂载的是2号卷映像，2号卷映像已经保存过了，不需再存，而XCOPY命令添加能自动启用内置管理员的功能也已经保存为3号卷映像，因此使用/discard 不保存 参数。/unmount-Wim是卸载映像挂载。

%PART%:$OEM$\imagex.exe /info %PART%:\install.wim 3 "Windows 8 标准版 64位 [Admin]" "Windows 8 标准版 64位 启用内置管理员"

REM 这是IMAGEX的/INFO命名命令，用来重命名第3号卷映像。新增的3号卷映像与2号映卷像名称相同，但功能不同，3号卷映像有启用内置管理员的功能。

ECHO.

ECHO -------------------以下是 Win8 PRO 及 WMC 映像处理------------------------

ECHO.

ECHO －－－PRO置入安装KEY

DISM /Mount-Wim /wimfile:%PART%:\install.wim /index:1 /MountDir:%PART%:\tempwim

REM 上行是挂载install.wim中的1号卷映像 专业版 ，不重复解释参数与用途。

Dism /Image: %PART%:\tempwim /Set-ProductKey:XKY4K-2NRWR-8F6P2-448RF-CRYQH

REM 上行是对临时挂载目录添加安装KEY。

DISM /commit-image /MountDir:%PART%:\tempwim

REM添加安装KEY后，临时挂载目录的内容发生了变化，将其保存进WIM中的1号卷映像。

ECHO －－－加入PRO ADMIN

xcopy %PART%:$OEM$$$ %PART%:\tempwim\windows /e /y

REM 上行是复制用于制作能自动启用内置管理 简称Admin 所需文件资料复制到临时挂载目录

DISM /commit-image /MountDir:%PART%:\tempwim /append

REM 使用/commit-image +/append组合向WIM添加一个卷映像。此前WIM中已经有3个卷映像了，这个是第4个。

ECHO －－－添加PRO WMC版本ADMIN

DISM /Image:%PART%:\tempwim /Set-Edition:ProfessionalWMC

REM 上行是使用/Set-Edition 版本升级命令 将临时挂载目录中的PRO版本升级为PRO WMC。

DISM /Image:%PART%:\tempwim /Set-ProductKey:RR3BN-3YY9P-9D7FC-7J4YF-QGJXW

REM 给临时挂载目录中的PRO WMC整合安装KEY。

DISM /commit-image /MountDir:%PART%:\tempwim /append

REM 在使用版本升级命令之前，临时挂载目录中的版本实际是自动启用内置管理的PRO版本。但经过版本升级后，临时挂载目录中的版本变成了启用内置管理的PRO WMC版本。所以，上一行是使用/commit-image +/append组合向WIM再添加一个卷映像，成为第5号卷映像。

ECHO －－－添加PRO WMC版本

DEL %PART%:\tempwim\Windows\Panther\unattend.xml /f /q

DEL %PART%:\tempwim\Windows\system32\ToDesktop.scf /f /q

DEL %PART%:\tempwim\Windows\ShutDown8.exe /f /q

RD %PART%:\tempwim\Windows\Setup\Scripts /s /q

REM 上几行是删除启用内置管理员的文件，这样就不会自动启用内置管理员了。因此，临时挂载目录的版本变成了不会自动启用内置管理员 WIN8默认是不是启用的 的PRO WMC版本。

DISM /commit-image /MountDir:%PART%:\tempwim /append

REM 同样，使用/commit-image +/append组合向WIM再添加一个卷映像，成为第6号卷映像。到这里，利用挂载的2号卷映像，我们成功地添加了3个卷映像 PRO ADMIN、PRO WMC ADMIN和PRO WMC 。

DISM /unmount-Wim /MountDir:%PART%:\tempwim /discard

REM 撤消挂载。挂载的2号卷映像前面保存过，这里不能再保存，必须使用/discard。

ECHO －－－对上述新的PRO映像重命名

%PART%:$OEM$\imagex.exe /info %PART%:\install.wim 4 "Windows 8 专业版 64位 [Admin]" "Windows 8 专业版 64位 启用内置管理员"

%PART%:$OEM$\imagex.exe /info %PART%:\install.wim 5 "Windows 8 专业版 64位 [Admin] [媒体中心]" "Windows 8 专业版 64位 [媒体中心] 启用内置管理员"

%PART%:$OEM$\imagex.exe /info %PART%:\install.wim 6 "Windows 8 专业版 64位 [媒体中心]" "Windows 8 专业版 64位 [媒体中心]"

REM 上三行对新增加的三个卷映像进行重命名

IF EXIST %PART%:\x64ent.wim (

ECHO -------------------以下是 Win8 Enterprise 映像处理------------------------

%PART%:\$OEM$\imagex.exe /info %PART%:\x64ent.wim 1 "Windows 8 企业版 64位" "Windows 8 企业版 64位"

DISM /Mount-Wim /wimfile:%PART%:\x64ent.wim /index:1 /MountDir:%PART%:\tempwim

Dism /Image:%PART%:\tempwim /Set-ProductKey:8M9BN-YB7W9-YV3VJ-7WMGG-MKH3V

DISM /commit-image /MountDir:%PART%:\tempwim

xcopy %PART%:\$OEM$\$$ %PART%:\tempwim\windows /e /y

DISM /commit-image /MountDir:%PART%:\tempwim /append

DISM /unmount-Wim /MountDir:%PART%:\tempwim /discard

%PART%:\$OEM$\imagex.exe /info %PART%:\x64ent.wim 2 "Windows 8 企业版 64位 [Admin]" "Windows 8 企业版 64位 启用内置管理员"

)

REM 上段“IF EXIST”开始，假设条件开头，如果分区根目录有x64ent.wim文件，也会进行将其挂载，并整合KEY与添加启用内置管理员的版本。

ECHO.

ECHO -------------------映像处理结束，开始合并映像------------------------

ECHO.

IF EXIST %PART%:\x64ent.wim (

DISM /Export-Image /SourceImageFile:%PART%:\x64ent.wim /SourceIndex:1 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

)

REM 上行，如果分区根目录有x64ent.wim文件，其第1号卷映像将被导出到X64WIN8ISO\sources目录，生成install.wim X64WIN8ISO\sources\install.wim ，其中第一号卷映像就是企业版。/Export-Image是导出命令，/SourceImageFile表示被导出的对象，/SourceIndex是卷映像编号，/DestinationImageFile是导出后的WIM文件路径与名称。X64WIN8ISO目录是我们需要的最终目录，该目录中的所有子目录和文件将被打包成最终需要的ISO文件。

DISM /Export-Image /SourceImageFile:%PART%:\install.wim /SourceIndex:2 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

REM 上行导出分区根目录的install.wim中的2号卷映像 标准版 到X64WIN8ISO\sources\install.wim中，X64WIN8ISO\sources\install.wim此时增加了一个卷映像 2号

DISM /Export-Image /SourceImageFile:%PART%:\install.wim /SourceIndex:1 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

REM 上行导出分区根目录的install.wim中的1号卷映像 专业版 到X64WIN8ISO\sources\install.wim中，X64WIN8ISO\sources\install.wim此时增加了一个卷映像 3号

DISM /Export-Image /SourceImageFile:%PART%:\install.wim /SourceIndex:6 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

REM 上行导出分区根目录的install.wim中的6号卷映像 专业版 WMC 到X64WIN8ISO\sources\install.wim中，X64WIN8ISO\sources\install.wim此时增加了一个卷映像 4号

IF EXIST %PART%:\x64ent.wim (

DISM /Export-Image /SourceImageFile:%PART%:\x64ent.wim /SourceIndex:2 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

)

REM上行，如果分区根目录有x64ent.wim文件，其第2号卷映像 企业版ADMIN 将被导出到X64WIN8ISO\sources\install.wim中去。

REM X64WIN8ISO\sources\install.wim此时增加了一个卷映像 5号

DISM /Export-Image /SourceImageFile:%PART%:\install.wim /SourceIndex:3 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

REM 上行导出分区根目录的install.wim中的3号卷映像 标准版 ADMIN 到X64WIN8ISO\sources\install.wim中，X64WIN8ISO\sources\install.wim此时增加了一个卷映像 6号

DISM /Export-Image /SourceImageFile:%PART%:\install.wim /SourceIndex:4 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

REM 上行导出分区根目录的install.wim中的4号卷映像 专业版 ADMIN 到X64WIN8ISO\sources\install.wim中，X64WIN8ISO\sources\install.wim此时增加了一个卷映像 7号

DISM /Export-Image /SourceImageFile:%PART%:\install.wim /SourceIndex:5 /DestinationImageFile:%PART%:\X64WIN8ISO\sources\install.wim

REM 上行导出分区根目录的install.wim中的5号卷映像 专业版 WMC ADMIN 到X64WIN8ISO\sources\install.wim中，X64WIN8ISO\sources\install.wim此时增加了一个卷映像 8号

ECHO 添加Server2012数据中心版、标准版的GUI版

IF EXIST %PART%:\x64Ser.wim (

DISM /Export-Image /SourceImageFile:%PART%:\x64Ser.wim /SourceIndex:2 /DestinationImageFile:%PART%:\x64WIN8ISO\sources\install.wim

DISM /Export-Image /SourceImageFile:%PART%:\x64Ser.wim /SourceIndex:4 /DestinationImageFile:%PART%:\x64WIN8ISO\sources\install.wim

)

REM 上几行，如果存在x64Ser.wim SERVER版本，特定命名 ，将其中的GUI版的卷映像导出到x64WIN8ISO\sources\install.wim

copy %PART%:$OEM$\ei.cfg %PART%:\X64WIN8ISO\sources /y

copy %PART%:$OEM$\product.ini %PART%:\X64WIN8ISO\sources /y

REM 复制两个文件指定目录，帮助安装程序正确识别x64WIN8ISO\sources\install.wim内部的所有卷映像版本。

del %PART%:\install.wim

REM 上行，删除分区根目录的install.wim，其内部的卷映像已经全部导出到x64WIN8ISO\sources\install.wim中了。

RD %PART%:\tempwim

REM 上行，删除挂载临时目录

cls

echo.

echo 成功制作多合一install.wim 在%PART%:\X64WIN8ISO\sources目录内

echo.

ECHO -------------------打包成可用于刻录的ISO文件 ？------------------------

echo.

echo 是否打包成ISO? 按任意键继续。

echo.

echo 如果不需要打包，则关闭本窗口。

echo.

pause >nul

echo.

%PART%:$OEM$\oscdimg.exe -u2 -b%PART%:\X64WIN8ISO\boot\etfsboot.com -h -lHRM_CCSA_X64FRE_ZH-CN_DV5 -t8/25/2012,00:00:00 %PART%:\X64WIN8ISO %PART%:\Win8_x64_Nin1.iso

REM 使用oscdimg.exe将X64WIN8ISO的全部内容打包成ISO。ISO格式u2，就是我们通常用ULTRAISO打开一个官方原版ISO文件看到的“可启动UDF”。Win8_x64_Nin1.iso是最终形成的文件名。具体不细说了，你还可以增加一些参数，见参考。

REM 参考http://technet.microsoft.com/zh-cn/library/cc749036(WS.10).aspx

ECHO.

ECHO -------------------制作结束-------------------

ECHO.

ECHO 请测试%PART%分区的Win8_x64_Nin1.iso

ECHO.

ECHO 按任意键退出

pause >nul

EXIT

:end

ECHO.

ECHO ~_~ 出错啦

ECHO.

ECHO 请检查所需文件夹和文件是否在此分区的根目录下。

ECHO.

ECHO 按任意键退出

pause >nul

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝以上是批处理注释，以下回答提问的内容＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

脱机添加NET3.5

将官方原版光盘SOURCES中的SXS目录和install.wim提取到F盘

md F:\temp_wim
dism /mount-image /imagefile:F:\install.wim /index:1 /mountdir:F:\temp_wim
dism /image:F:\temp_wim /enable-feature /featurename:netfx3 /all /source:F:\SXS /limitaccess
Dism /Unmount-Image /MountDir:F:\temp_wim /Commit
rem 这样F:\install.wim中的第1个卷映像添加了NET3.5

dism /mount-image /imagefile:F:\install.wim /index:2 /mountdir:F:\temp_wim
dism /image:F:\temp_wim /enable-feature /featurename:netfx3 /all /source:F:\SXS /limitaccess
Dism /Unmount-Image /MountDir:F:\temp_wim /Commit
rem 这样F:\install.wim中的第2个卷映像添加了NET3.5

pause

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

提示：想知道某个WIM文件中有多少个卷映像版本，以下命令可查。

dism /get-imageinfo /imagefile:F:\install.wim >F:\wiminfo.txt

rem 看一下F:\wiminfo.txt就知道这个WIM有几个卷映像。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝结束＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

城通盘：WIN8映像合并一键批处理

城通盘：WIN8映像合并一键批处理(注释)－－－WORD版本